rem ###########################################################################
rem # The following variables are assumed to be set externally.
rem #
rem # javaClass
rem # javaFlags
rem # classPathPrefix
rem ###########################################################################

set installDir=%~dp0..

rem ###########################################################################
rem # Set variables
rem ###########################################################################
call "%installDir%\bin\setEnv.bat"

if not defined BAANHOME (
 set errorMessage=BAANHOME environment variable not defined
 goto error
)
if not defined OW_C4JAVA_HOME (
 set errorMessage=OW_C4JAVA_HOME environment variable not defined
 goto error
)

set CLASSPATH=%classPathPrefix%
set CLASSPATH=%CLASSPATH%;%BAANHOME%\java\com_baan_bclm.jar
set CLASSPATH=%CLASSPATH%;%OW_C4JAVA_HOME%\java\ow.jar
set CLASSPATH=%CLASSPATH%;%OW_C4JAVA_HOME%\java\ow3p.jar
set CLASSPATH=%CLASSPATH%;%OW_C4JAVA_HOME%\java\owxml.jar
set CLASSPATH=%CLASSPATH%;%OW_C4JAVA_HOME%\java\erprt.jar
set CLASSPATH=%CLASSPATH%;%OW_C4JAVA_HOME%\java
rem Unset classPathPrefix so it doesn't show up in the next line's output
set classPathPrefix=
set CLASSPATH
set Path="%BAANHOME%"\shlib;%Path%
set Path="%BAANHOME%"\bin;%Path%
set Path
if defined DEBUG (
 set JVM_OPTIONS=%JVM_OPTIONS% -Dcom.ssa.ta.taxprovider.debug=true -Dshow.log.facility=true
)
set JVM_OPTIONS

rem ###########################################################################
rem # Construct command line
rem ###########################################################################
set commandLine="%JAVA_CMD%" %JVM_OPTIONS% %javaFlags% %javaClass% %*

rem ###########################################################################
rem # Do the call
rem ###########################################################################
echo.
echo Executing:
echo %commandLine%
echo.
%commandLine%
if errorlevel 1 (
 set errorMessage=Java program exited with failure code %errorlevel%
 goto error
)

rem ###########################################################################
rem # Clean up
rem ###########################################################################
:endloc
exit /b 0

:error
echo.
echo *** ERROR ***
echo %errorMessage%
echo Exiting
pause
exit /b 1
